home *** CD-ROM | disk | FTP | other *** search
/ SPACE 2 / SPACE - Library 2 - Volume 1.iso / misc / 642 / sdocsata / anomaly.e next >
Encoding:
Text File  |  1991-08-06  |  13.5 KB  |  576 lines
  1. C The triangle anomaly.
  2.   Letter to Jackiw, Jan 20, 1991.
  3.  
  4. C Anomaly 1. Evaluation of the coefficients C(i,j), i=1,2, in terms
  5.      of C0 and B0.
  6. C Anomaly 2. The axial current triangle graphs. Vertex:  i*G5*G(al).
  7. C Anomaly 3. The axial current triangle graphs. Vertex:  i*G5*G(al).
  8.      An expansion in terms of the external momenta is done
  9.      (assuming them to be small with respect to the loop mass m).
  10.      The result shows that the axial current is at least of third
  11.      order in the momenta.
  12. C Anomaly 4. The pseudo scalar graphs. Vertex: 2*m*G5.
  13.  
  14. *end
  15.  
  16. C Anomaly 1. Evaluation of the coefficients C(i,j), i=1,2, in terms
  17.      of C0 and B0.
  18.  
  19. P ninput
  20.  
  21. BLOCK BFUN{}
  22. Id,B22(x~,M~,m~)=(-0.5*Ax(m)+M**2*B0(x,M,m)
  23.       -0.5*(x+m^2-M**2)*B1(x,M,m))/[1-N]
  24. Id,B21(x~,M~,m~)=-((0.5*N-1)*Ax(m)
  25.        -0.5*N*(x+m^2-M**2)*B1(x,M,m)
  26.        +M**2*B0(x,M,m) )/x/[1-N]
  27. Id,B1(x~,M~,m~)= (0.5*Ax(M)-0.5*Ax(m)
  28.               -0.5*(x+m^2-M**2)*B0(x,M,m) )/x
  29. ENDBLOCK
  30.  
  31.  
  32. BLOCK CASE6{}
  33.  
  34. C Case: all masses equal.
  35.  
  36. Id,M3=m
  37. Al,M2=m
  38. Al,M1=m
  39. Al,B0(x~,M1~,M2~)=B0(x,m)
  40. Id,Ax(M1~)=Ax(m)
  41. Al,B0(x~,M1~,M2~)=B0(x,m)
  42. ENDBLOCK
  43.  
  44. A Pi,N,N_,m,M,M1,M2,M3,x,y
  45. V p,k
  46. F Ax
  47.  
  48. D XX(I)= pDp,-pDk,-pDk,kDk
  49.  
  50. X X(I,J)= XX( 2*I-2+J )/Det
  51.  
  52. X f1=M1^2-M2^2-kDk
  53. X f2=M2^2-M3^2-pDp-2*pDk
  54. *fix
  55.  
  56. D R1(I)=(1/2*f1*c0+1/2*B0(qDq,M1,M3)-1/2*B0(pDp,M2,M3)),
  57.  (1/2*f2*c0 + B0(kDk,M1,M2)/2 - B0(qDq,M1,M3)/2)
  58.  
  59. Z c11=DS(K,1,2,(X(1,K)*R1(K)))
  60. Z c12=DS(K,1,2,(X(2,K)*R1(K)))
  61. Id,Multi,pDk^2=kDk*pDp-Det
  62. Keep c11,c12
  63. B i,Pi,Det,c0
  64. CASE6{}
  65. *next
  66.  
  67. Z c24=i*Pi^2/4-1/2*M1^2*c0+1/4*(B0(pDp,M2,M3)-f1*c11-f2*c12)
  68.  
  69. Id,Multi,pDk^2=kDk*pDp-Det
  70. CASE6{}
  71. B i,Pi,Det,c0
  72. Keep c11,c12,c24
  73. *next
  74.  
  75. D R3(I)=(1/2*f1*c11+1/2*B1(qDq,M1,M3)+1/2*B0(pDp,M2,M3)-c24),
  76.  (1/2*f2*c11+1/2*B1(kDk,M1,M2)-1/2*B1(qDq,M1,M3))
  77. D R4(I)=(1/2*f1*c12+1/2*B1(qDq,M1,M3)-1/2*B1(pDp,M2,M3)),
  78.  (1/2*f2*c12-1/2*B1(qDq,M1,M3)-c24)
  79.  
  80. Z c21=DS(K,1,2,(X(1,K)*R3(K)))
  81. Z c23=DS(K,1,2,(X(2,K)*R3(K)))
  82.  
  83. Z C23p=DS(K,1,2,(X(1,K)*R4(K)))
  84. Z c22=DS(K,1,2,(X(2,K)*R4(K)))
  85.  
  86. B i,Pi,Det,c0
  87. BFUN{}
  88. Id,Multi,pDk^2=kDk*pDp-Det
  89. Id,N*[1-N]^-1=-1+[1-N]^-1
  90. Id,Ax(m~)*[1-N]^-1= -1/3*Ax(m) + 2*i*Pi^2*m^2/9
  91. Al,B0(x~,M~,m~)*[1-N]^-1= -1/3*B0(x,M,m) - 2*i*Pi^2/9
  92. CASE6{}
  93. Keep c11,c12,c24,c21,c23,C23p,c22
  94. Nprint C23p
  95. *next
  96. P input
  97.  
  98. C Check: must be zero.
  99.  
  100. Z Diff23=c23-C23p
  101. *end
  102.  
  103. C Anomaly 2. The axial current triangle graphs. Vertex:  i*G5*G(al).
  104.  
  105. C The triangle anomaly.
  106.   Computing the axial current.
  107.   The expressions for the C(i,j) have been computed separately,
  108.   and are contained in the block CFU.
  109.  
  110. P ninput
  111. BLOCK CFU{}
  112. P ninput
  113. Id,C(1,1,m) = 
  114.  + Det^-1*C0(m)
  115.   * ( 1/2*pDp*pDk + 1/2*pDp*kDk )
  116.  
  117.  - C0(m)
  118.  
  119.  + B0(pDp,m)*Det^-1
  120.   * ( - 1/2*pDp )
  121.  
  122.  + B0(kDk,m)*Det^-1
  123.   * ( - 1/2*pDk )
  124.  
  125.  + B0(qDq,m)*Det^-1
  126.   * ( 1/2*pDp + 1/2*pDk )
  127.  
  128. Al,C(1,2,m) = 
  129.  + Det^-1*C0(m)
  130.   * ( - 1/2*pDp*kDk - 1/2*pDk*kDk )
  131.  
  132.  + B0(pDp,m)*Det^-1
  133.   * ( 1/2*pDk )
  134.  
  135.  + B0(kDk,m)*Det^-1
  136.   * ( 1/2*kDk )
  137.  
  138.  + B0(qDq,m)*Det^-1
  139.   * ( - 1/2*pDk - 1/2*kDk ) + 0.
  140.  
  141.  
  142. Al,C(2,4,m) = 
  143.  + 1/4*i*Pi^2
  144.  
  145.  + Det^-1*C0(m)
  146.   * ( - 1/4*pDp*pDk*kDk - 1/8*pDp*kDk^2 - 1/8*pDp^2*kDk )
  147.  
  148.  + C0(m)
  149.   * ( - 1/2*m^2 )
  150.  
  151.  + B0(pDp,m)*Det^-1
  152.   * ( 1/8*pDp*pDk + 1/8*pDp*kDk )
  153.  
  154.  + B0(kDk,m)*Det^-1
  155.   * ( 1/8*pDp*kDk + 1/8*pDk*kDk )
  156.  
  157.  + 1/4*B0(qDq,m)
  158.  
  159.  + B0(qDq,m)*Det^-1
  160.   * ( - 1/8*pDp*pDk - 1/4*pDp*kDk - 1/8*pDk*kDk ) + 0.
  161.  
  162.  
  163. Al,C(2,1,m) = 
  164.  + i*Pi^2*Det^-1
  165.   * ( - 1/4*pDp )
  166.  
  167.  + Det^-2*C0(m)
  168.   * ( 3/4*pDp^2*pDk*kDk + 3/8*pDp^2*kDk^2 + 3/8*pDp^3*kDk )
  169.  
  170.  + Det^-1*C0(m)
  171.   * ( 1/2*m^2*pDp - pDp*pDk - pDp*kDk - 1/4*pDp^2 )
  172.  
  173.  + C0(m)
  174.  
  175.  + B0(pDp,m)*Det^-2
  176.   * ( - 3/8*pDp^2*pDk - 3/8*pDp^2*kDk )
  177.  
  178.  + B0(pDp,m)*Det^-1
  179.   * ( pDp )
  180.  
  181.  + B0(kDk,m)*Det^-2
  182.   * ( - 3/8*pDp*pDk*kDk - 3/8*pDp^2*kDk )
  183.  
  184.  + B0(kDk,m)*Det^-1
  185.   * ( 1/4*pDp + 3/4*pDk )
  186.  
  187.  + B0(qDq,m)*Det^-2
  188.   * ( 3/8*pDp*pDk*kDk + 3/8*pDp^2*pDk + 3/4*pDp^2*kDk )
  189.  
  190.  + B0(qDq,m)*Det^-1
  191.   * ( - 5/4*pDp - 3/4*pDk )
  192.  
  193. Al,C(2,3,m) = 
  194.  + i*Pi^2*Det^-1
  195.   * ( 1/4*pDk )
  196.  
  197.  + Det^-2*C0(m)
  198.   * ( - 3/8*pDp*pDk*kDk^2 - 3/8*pDp^2*pDk*kDk - 3/4*pDp^2*kDk^2 )
  199.  
  200.  + Det^-1*C0(m)
  201.   * ( - 1/2*m^2*pDk + pDp*kDk + 1/2*pDk*kDk )
  202.  
  203.  + B0(pDp,m)*Det^-2
  204.   * ( 3/8*pDp*pDk*kDk + 3/8*pDp^2*kDk )
  205.  
  206.  + B0(pDp,m)*Det^-1
  207.   * ( - 1/8*pDp - 1/2*pDk )
  208.  
  209.  + B0(kDk,m)*Det^-2
  210.   * ( 3/8*pDp*pDk*kDk + 3/8*pDp*kDk^2 )
  211.  
  212.  + B0(kDk,m)*Det^-1
  213.   * ( - 5/8*kDk )
  214.  
  215.  + B0(qDq,m)*Det^-2
  216.   * ( - 3/4*pDp*pDk*kDk - 3/8*pDp*kDk^2 - 3/8*pDp^2*kDk )
  217.  
  218.  + B0(qDq,m)*Det^-1
  219.   * ( 1/8*pDp + 1/2*pDk + 5/8*kDk )
  220.  
  221. Al,C(2,2,m) = 
  222.  + i*Pi^2*Det^-1
  223.   * ( - 1/4*kDk )
  224.  
  225.  + Det^-2*C0(m)
  226.   * ( 3/4*pDp*pDk*kDk^2 + 3/8*pDp*kDk^3 + 3/8*pDp^2*kDk^2 )
  227.  
  228.  + Det^-1*C0(m)
  229.   * ( 1/2*m^2*kDk - 1/4*kDk^2 )
  230.  
  231.  + B0(pDp,m)*Det^-2
  232.   * ( - 3/8*pDp*pDk*kDk - 3/8*pDp*kDk^2 )
  233.  
  234.  + B0(pDp,m)*Det^-1
  235.   * ( - 1/4*pDk + 1/4*kDk )
  236.  
  237.  + B0(kDk,m)*Det^-2
  238.   * ( - 3/8*pDp*kDk^2 - 3/8*pDk*kDk^2 )
  239.  
  240.  + B0(qDq,m)*Det^-2
  241.   * ( 3/8*pDp*pDk*kDk + 3/4*pDp*kDk^2 + 3/8*pDk*kDk^2 )
  242.  
  243.  + B0(qDq,m)*Det^-1
  244.   * ( 1/4*pDk - 1/4*kDk ) + 0.
  245. P input
  246. ENDBLOCK
  247. P input
  248.  
  249. V p,r,q,k
  250. I al,mu,nu,L1,L2,L3
  251. A N,N_,Pi,m,Ax,Det
  252. F Fx,Cx,C,c,C0,Bx,B0,B1
  253.  
  254. C  Triangle graphs.
  255.    (k,al) => (p,mu),(q,nu) with all momenta pointing inwards.
  256.    There are two graphs, differing with respect to each other by
  257.    reversal of the fermion direction (or by the interchange p <=> q
  258.    and mu <=> nu).
  259.  
  260. Z A(al,mu,nu) =
  261.  - i*Cx(m)*G5(1,2)*G(2,3,al)*
  262.            (i*G(3,4,k) + i*G(3,4,r) + m*Gi(3,4))
  263.            *G(4,5,mu)*
  264.            (i*G(5,6,r) + i*G(5,6,k) + i*G(5,6,p) + m*Gi(5,6))
  265.           *G(6,7,nu)*
  266.            (i*G(7,1,r) + m*Gi(7,1))*Ax
  267.  
  268.  - i*Cx(m)*G5(1,2)*G(2,3,al)*
  269.            (- i*G(3,4,r) + m*Gi(3,4))
  270.            *G(4,5,nu)*
  271.            (- i*G(5,6,r) - i*G(5,6,k) - i*G(5,6,p) + m*Gi(5,6))
  272.           *G(6,7,mu)*
  273.            (- i*G(7,1,r) - i*G(7,1,k) + m*Gi(7,1))*Ax
  274.  
  275. Id,Gammas,"C
  276. *yep
  277.  
  278. C Try to work out terms with three r, to avoid the C(3,i).
  279.   Such terms have more than one r inside the trace.
  280.   Move them towards each other, to produce rDr
  281.   Do this by moving them to the right.
  282.  
  283. Id,G(1,"t,"4,G5,al,r,L1~,L2~,L3~,L4~) =
  284.  - G(1,"t,"4,G5,al,L1,r,L2,L3,L4)
  285.  + 2*D(L1,r)*G(1,"t,"4,G5,al,L2,L3,L4)
  286. Id,G(1,"t,"4,G5,al,L2~,r,L1~,L3~,L4~) =
  287.  - G(1,"t,"4,G5,al,L2,L1,r,L3,L4)
  288.  + 2*D(L1,r)*G(1,"t,"4,G5,al,L2,L3,L4)
  289. Id,G(1,"t,"4,G5,al,L2~,L3~,r,L1~,L4~) =
  290.  - G(1,"t,"4,G5,al,L2,L3,L1,r,L4)
  291.  + 2*D(L1,r)*G(1,"t,"4,G5,al,L2,L3,L4)
  292. Id,G(1,"t,"4,G5,al,L2~,L3~,L4~,r,L1~) =
  293.  - G(1,"t,"4,G5,al,L2,L3,L4,L1,r)
  294.  + 2*D(L1,r)*G(1,"t,"4,G5,al,L2,L3,L4)
  295. Id,Gammas,"C
  296. Id,G(1,"t,"4,G5,al,r,L1~,L2~,L3~,L4~) =
  297.  - G(1,"t,"4,G5,al,L1,r,L2,L3,L4)
  298.  + 2*D(L1,r)*G(1,"t,"4,G5,al,L2,L3,L4)
  299. Id,G(1,"t,"4,G5,al,L2~,r,L1~,L3~,L4~) =
  300.  - G(1,"t,"4,G5,al,L2,L1,r,L3,L4)
  301.  + 2*D(L1,r)*G(1,"t,"4,G5,al,L2,L3,L4)
  302. Id,G(1,"t,"4,G5,al,L2~,L3~,r,L1~,L4~) =
  303.  - G(1,"t,"4,G5,al,L2,L3,L1,r,L4)
  304.  + 2*D(L1,r)*G(1,"t,"4,G5,al,L2,L3,L4)
  305. Id,G(1,"t,"4,G5,al,L2~,L3~,L4~,r,L1~) =
  306.  - G(1,"t,"4,G5,al,L2,L3,L4,L1,r)
  307.  + 2*D(L1,r)*G(1,"t,"4,G5,al,L2,L3,L4)
  308. Id,Gammas,"C
  309. *yep
  310.  
  311. C There may still be some traces with two r's left.
  312.  
  313. Id,G(1,"t,"4,G5,al,r,L1~,L2~) =
  314.  - G(1,"t,"4,G5,al,L1,r,L2)
  315. Id,Gammas,"C
  316. *yep
  317.  
  318. C Work out the rDr terms, writing rDr = rDr+m^2 - m^2.
  319.   In the resulting two point function one has
  320.   1/((r+k)^2+m^2)*((r+p+k)^2+m^2). Shift r => r-k.
  321.  
  322. IF Cx(m)*rDr=Bx(m)*Shift - Cx(m)*m^2
  323. IF Shift=1
  324. Id,r(mu~)=r(mu)-k(mu)
  325. Al,Func,r(mu~)=r(mu)-k(mu)
  326. Al,Dotpr,r(mu~)=r(mu)-k(mu)
  327. ENDIF
  328. ENDIF
  329. Id,Gammas,"C
  330. *yep
  331.  
  332. C Now do the integration over the loop momentum r.
  333.  
  334. Id,All,r,N,Fx
  335.  
  336. Id,Adiso,Cx(m)*Fx(L1~,L2~)=
  337.  + k(L1)*k(L2)*C(2,1,m) + p(L1)*p(L2)*C(2,2,m)
  338.  + k(L1)*p(L2)*C(2,3,m) + p(L1)*k(L2)*C(2,3,m)
  339.  + D(L1,L2)*C(2,4,m)
  340. Id,Adiso,Cx(m)*Fx(L1~) = k(L1)*C(1,1,m) + p(L1)*C(1,2,m)
  341. Al,Adiso,Bx(m)*Fx(L1~) = p(L1)*B1(pDp,m)
  342. Id,Cx(m)= C0(m)
  343. Al,Bx(m)= B0(pDp,m)
  344.  
  345. Id,Gammas
  346. *yep
  347.  
  348. C Work out the C(i,j).
  349.  
  350. CFU{}
  351.  
  352. Id,B1(x~,m) = -0.5*B0(x,m)
  353.  
  354. Id,p(al)*Epf(mu,nu,la~,ka~)=
  355.     p(mu)*Epf(al,nu,la,ka)
  356.   + p(nu)*Epf(mu,al,la,ka)
  357.   + p(la)*Epf(mu,nu,al,ka)
  358.   + p(ka)*Epf(mu,nu,la,al)
  359. Al,k(al)*Epf(mu,nu,la~,ka~)=
  360.     k(mu)*Epf(al,nu,la,ka)
  361.   + k(nu)*Epf(mu,al,la,ka)
  362.   + k(la)*Epf(mu,nu,al,ka)
  363.   + k(ka)*Epf(mu,nu,la,al)
  364.  
  365. Id,Multi,pDk^2=kDk*pDp-Det
  366. Id,Det=kDk*pDp-pDk^2
  367.  
  368. *yep
  369.  
  370. C Write the result, i.e. the axial current, in the more standard form.
  371.  
  372. Id,k(mu~)=-q(mu)-p(mu)
  373. Id,Func,k(mu~)=-q(mu)-p(mu)
  374. Id,Dotpr,k(mu~)=-q(mu)-p(mu)
  375. Id,Multi,pDq^2=qDq*pDp-Det
  376. P output
  377. *yep
  378.  
  379. C Take any one of the following three options.
  380.  
  381. Id,Ax=k(al)        ! Taking the divergence of the axial current.
  382. C Id,Ax=p(mu)        ! Must be zero: gauge invariance.
  383. C Id,Ax=q(nu)        ! Must be zero: gauge invariance.
  384. Id,k(mu~)=-q(mu)-p(mu)
  385. Id,Func,k(mu~)=-q(mu)-p(mu)
  386. Id,Dotpr,k(mu~)=-q(mu)-p(mu)
  387. Id,Multi,pDq^2=qDq*pDp-Det
  388. *end
  389.  
  390. C Anomaly 3. The axial current triangle graphs. Vertex:  i*G5*G(al).
  391.      An expansion in terms of the external momenta is done
  392.      (assuming them to be small with respect to the loop mass m).
  393.      The result shows that the axial current is at least of third
  394.      order in the momenta.
  395.  
  396. C The triangle anomaly.
  397.   Computing the axial current to order 3 in the external momenta.
  398.  
  399. V p,r,q,k
  400. I al,mu,nu,L1,L2,L3,L4
  401. A N,N_,Pi,m,Ax,ax,Det,Den
  402. F Ln,Fx,Cx,C,c,C0,Bx,B0,B1
  403. X DY(L1,L2,L3,L4)=D(L1,L2)*D(L3,L4)+D(L1,L3)*D(L2,L4)+D(L1,L4)*D(L2,L3)
  404. X DZ(L1,L2,L3,L4,L5,L6)=
  405.    D(L1,L2)*DY(L3,L4,L5,L6)
  406.  + D(L1,L3)*DY(L2,L4,L5,L6)
  407.  + D(L1,L4)*DY(L3,L2,L5,L6)
  408.  + D(L1,L5)*DY(L3,L4,L2,L6)
  409.  + D(L1,L6)*DY(L3,L4,L5,L2)
  410.  
  411. C  Triangle graphs.
  412.    (k,al) => (p,mu),(q,nu) with all momenta pointing inwards.
  413.    There are two graphs, differing with respect to each other by
  414.    reversal of the fermion direction (or by the interchange p <=> q
  415.    and mu <=> nu).
  416.  
  417. Z A(al,mu,nu) =
  418.  - i*Cx(m)*G5(1,2)*G(2,3,al)*
  419.            (i*G(3,4,k) + i*G(3,4,r) + m*Gi(3,4))
  420.            *G(4,5,mu)*
  421.            (i*G(5,6,r) + i*G(5,6,k) + i*G(5,6,p) + m*Gi(5,6))
  422.           *G(6,7,nu)*
  423.            (i*G(7,1,r) + m*Gi(7,1))*Ax
  424.  
  425.  - i*Cx(m)*G5(1,2)*G(2,3,al)*
  426.            (- i*G(3,4,r) + m*Gi(3,4))
  427.            *G(4,5,nu)*
  428.            (- i*G(5,6,r) - i*G(5,6,k) - i*G(5,6,p) + m*Gi(5,6))
  429.           *G(6,7,mu)*
  430.            (- i*G(7,1,r) - i*G(7,1,k) + m*Gi(7,1))*Ax
  431.  
  432. Id,Gammas,"C
  433.  
  434. C Cx(m) is the three point function:
  435.    1 / (r^2+m^2)*((r+k)^2+m^2)*((r+k+p)^2+m^2)
  436.   Expand the second and third denominator, use k+p = -q. Below Den stands
  437.   for 1/(r^2+m^2).
  438.  
  439. Id,Cx(m)=Den^3*Dev2*Dev3
  440. Id,Dev2= 1 - (2*kDr+kDk)*Den + (2*kDr+kDk)^2*Den^2 - (2*kDr+kDk)^3*Den^3
  441. Al,Dev3= 1 - (-2*qDr+qDq)*Den + (-2*qDr+qDq)^2*Den^2 - (-2*qDr+qDq)^3*Den^3
  442. Id,Multi,Den^7=0
  443. *yep
  444. Id,All,r,N,Fx
  445.  
  446. C Keep up to and including third order.
  447.  
  448. Id,Count,ax,"F,G,"F,Fx,k,1,q,1,p,1
  449. Id,Multi,ax^4=0
  450. Id,ax=1
  451.  
  452. C Doing the momentum integrals.
  453.  
  454. Id,Fx(L1~,L2~,L3~,L4~,L5~)=0
  455. Al,Fx(L1~,L2~,L3~)=0
  456. Al,Fx(L1~)=0
  457.  
  458. Id,Fx(L1~,L2~,L3~,L4~,L5~,L6~)*Den^6 =
  459.  DZ(L1,L2,L3,L4,L5,L6)*i*Pi^2/960/m^2
  460. Al,Fx(L1~,L2~,L3~,L4~,L5~,L6~)*Den^5 =
  461.  DZ(L1,L2,L3,L4,L5,L6)*(i*DEL/192-i*Pi^2/192*Ln(m))
  462. Al,Fx(L1~,L2~,L3~,L4~,L5~,L6~)*Den^4 =
  463.  DZ(L1,L2,L3,L4,L5,L6)*m^2*(-i*DEL/48+i*Pi^2/48*(-1+Ln(m)))
  464.  
  465. Id,Fx(L1~,L2~,L3~,L4~)*Den^6 = i*Pi^2/480/m^4*DY(L1,L2,L3,L4)
  466. Al,Fx(L1~,L2~,L3~,L4~)*Den^5 = i*Pi^2/96/m^2*DY(L1,L2,L3,L4)
  467. Al,Fx(L1~,L2~,L3~,L4~)*Den^4 =
  468.  DY(L1,L2,L3,L4)*(i*DEL/24 - i*Pi^2/24*Ln(m))
  469. Al,Fx(L1~,L2~,L3~,L4~)*Den^3 =
  470.  DY(L1,L2,L3,L4)*m^2*(-i*DEL/8 + i*Pi^2/8*(-1 + Ln(m)))
  471.  
  472. Id,Fx(L1~,L2~)*Den^5 = i*Pi^2/48/m^4*D(L1,L2)
  473. Al,Fx(L1~,L2~)*Den^4 = i*Pi^2/12/m^2*D(L1,L2)
  474. Al,Fx(L1~,L2~)*Den^3 = D(L1,L2)*(i*DEL/4 - i*Pi^2/4*Ln(m))
  475.  
  476. Id,Den^5=i*Pi^2/12/m^6
  477. Al,Den^4=i*Pi^2/6/m^4
  478. Al,Den^3=i*Pi^2/2/m^2
  479.  
  480. *yep
  481.  
  482. C Take the trace.
  483.  
  484. B DEL,i,Pi
  485. Id,Gammas
  486. *yep
  487.  
  488. Id,Multi,m^-4=0
  489. Id,N=4+N_
  490. Id,N_*DEL=-2*Pi^2
  491. Id,N_=0
  492. Id,k(mu~)=-q(mu)-p(mu)
  493. Al,Func,k(mu~)=-q(mu)-p(mu)
  494. Al,Dotpr,k(mu~)=-q(mu)-p(mu)
  495. *yep
  496.  
  497. Id,p(al)*Epf(mu,nu,la~,ka~)=
  498.     p(mu)*Epf(al,nu,la,ka)
  499.   + p(nu)*Epf(mu,al,la,ka)
  500.   + p(la)*Epf(mu,nu,al,ka)
  501.   + p(ka)*Epf(mu,nu,la,al)
  502. Al,q(al)*Epf(mu,nu,la~,ka~)=
  503.     q(mu)*Epf(al,nu,la,ka)
  504.   + q(nu)*Epf(mu,al,la,ka)
  505.   + q(la)*Epf(mu,nu,al,ka)
  506.   + q(ka)*Epf(mu,nu,la,al)
  507.  
  508. P output
  509. *yep
  510.  
  511. C Take any one of the following three options.
  512.  
  513. C Id,Ax=k(al)        ! Taking the divergence of the axial current.
  514. C Id,Ax=p(mu)        ! Must be zero: gauge invariance.
  515. Id,Ax=q(nu)        ! Must be zero: gauge invariance.
  516. Id,k(mu~)=-q(mu)-p(mu)
  517. Id,Func,k(mu~)=-q(mu)-p(mu)
  518. Id,Dotpr,k(mu~)=-q(mu)-p(mu)
  519. *end
  520.  
  521. C Anomaly 4. The pseudo scalar graphs. Vertex: 2*m*G5.
  522.  
  523. C The triangle anomaly.
  524.   Computing the pseudo scalar triangle diagrams.
  525.  
  526. V p,r,q,k
  527. I al,mu,nu,L1,L2,L3
  528. A N,N_,Pi,m,Ax,Det
  529. F Fx,Cx,C,c,C0,Bx,B0,B1
  530.  
  531. C  Triangle graphs.
  532.    (k) => (p,mu),(q,nu) with all momenta pointing inwards.
  533.    There are two graphs, differing with respect to each other by
  534.    reversal of the fermion direction (or by the interchange p <=> q
  535.    and mu <=> nu).
  536.  
  537. Z A(al,mu,nu) =
  538.  -   Cx(m)*G5(1,3)*2*m*
  539.            (i*G(3,4,k) + i*G(3,4,r) + m*Gi(3,4))
  540.            *G(4,5,mu)*
  541.            (i*G(5,6,r) + i*G(5,6,k) + i*G(5,6,p) + m*Gi(5,6))
  542.           *G(6,7,nu)*
  543.            (i*G(7,1,r) + m*Gi(7,1))*Ax
  544.  
  545.  -   Cx(m)*G5(1,3)*2*m*
  546.            (- i*G(3,4,r) + m*Gi(3,4))
  547.            *G(4,5,nu)*
  548.            (- i*G(5,6,r) - i*G(5,6,k) - i*G(5,6,p) + m*Gi(5,6))
  549.           *G(6,7,mu)*
  550.            (- i*G(7,1,r) - i*G(7,1,k) + m*Gi(7,1))*Ax
  551.  
  552. Id,Gammas,"C
  553. *yep
  554.  
  555. C Now do the integration over the loop momentum r.
  556.  
  557. Id,All,r,N,Fx
  558.  
  559. Id,Adiso,Cx(m)*Fx(L1~,L2~)=
  560.  + k(L1)*k(L2)*C(2,1,m) + p(L1)*p(L2)*C(2,2,m)
  561.  + k(L1)*p(L2)*C(2,3,m) + p(L1)*k(L2)*C(2,3,m)
  562.  + D(L1,L2)*C(2,4,m)
  563. Id,Adiso,Cx(m)*Fx(L1~) = k(L1)*C(1,1,m) + p(L1)*C(1,2,m)
  564.  
  565. Id,Cx(m)= C0(m)
  566.  
  567. Id,Gammas
  568.  
  569. C Write the result in the more standard form.
  570.  
  571. Id,k(mu~)=-q(mu)-p(mu)
  572. Id,Func,k(mu~)=-q(mu)-p(mu)
  573. Id,Dotpr,k(mu~)=-q(mu)-p(mu)
  574. Id,Multi,pDq^2=qDq*pDp-Det
  575. *end
  576. ə